Initial population

2026-03-07 19:38:21 -06:00
commit 46735bddd3
59 changed files with 12911 additions and 0 deletions
--- a/OrganLitWorksByComposer.xsl
+++ b/OrganLitWorksByComposer.xsl
@@ -0,0 +1,91 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
+<xsl:output method="html" version="4.01" encoding="UTF-8" indent="yes"/>
+<xsl:template match="/">
+<html>
+	<head>
+		<title>OrganLit - Works By Composer</title>
+	</head>
+	<body>
+			<h1>Works By Composer</h1>
+			<xsl:for-each select="//OrganLit/Composers/Composer">
+				<xsl:sort select="ComposerName"/>
+				<xsl:call-template name="FormatComposer"/>
+			</xsl:for-each>
+		<br/>
+		<br/>
+		<a href="index.htm">OrganLit Home</a>
+	</body>
+</html>
+</xsl:template>
+
+<xsl:template name="FormatComposer">
+	<p>
+	<a name="{current()/ComposerID}"/>
+	<br><b><xsl:value-of select="ComposerName"/></b></br>
+	<xsl:for-each select="../../Works/Work[ComposerID=current()/ComposerID]">
+		<xsl:sort select="WorkName"/>
+		<xsl:sort select="Book/BookTitle"/>
+		<xsl:sort select="Book/Composer/ComposerName"/>
+		<xsl:sort select="Book/PageNumber" data-type="number"/>
+		<xsl:call-template name="FormatWorks"/>
+	</xsl:for-each>
+	</p>
+</xsl:template>
+
+<xsl:template name="FormatWorks">
+	<br>
+	<xsl:text>&quot;</xsl:text><xsl:value-of select="WorkName"/>
+	<xsl:if test="OpusInfo!=''"><xsl:text> - </xsl:text><xsl:value-of select="OpusInfo"/></xsl:if>
+	<xsl:text>&quot;</xsl:text>
+	<xsl:text> </xsl:text>
+	<xsl:variable name="WorkComposerID" select="current()/ComposerID"/>
+	<xsl:for-each select="current()/Book">
+		<xsl:call-template name="FormatBookTitleAndLocation">
+			<xsl:with-param name="WorkComposerID" select="$WorkComposerID"/>
+		</xsl:call-template>
+	</xsl:for-each>
+	<xsl:choose>
+		<xsl:when test="PageNumber=''"/>
+		<xsl:when test="PageNumber='0'"/>
+		<xsl:otherwise>
+			<xsl:text> p. </xsl:text><xsl:value-of select="PageNumber"/>
+		</xsl:otherwise>
+	</xsl:choose>
+	</br>
+	<br/>
+</xsl:template>
+
+<xsl:template name="FormatBookTitleAndLocation">
+	<xsl:param name="WorkComposerID"/>
+	<i><xsl:value-of select="BookTitle"/></i><xsl:text> </xsl:text>
+	<xsl:choose>
+		<xsl:when test="ComposerID=''">
+			<xsl:choose>
+				<xsl:when test="PublisherID=''">
+					<xsl:text>(Collection)</xsl:text>
+				</xsl:when>
+				<xsl:otherwise>
+					<xsl:text>(Collection - </xsl:text><xsl:value-of select="Publisher/PublisherName"/><xsl:text>)</xsl:text>
+				</xsl:otherwise>
+			</xsl:choose>
+		</xsl:when>
+		<xsl:otherwise>
+			<xsl:if test="ComposerID!=$WorkComposerID">
+				<xsl:text>(filed under </xsl:text>
+				<xsl:value-of select="current()/Composer/ComposerName"/>
+				<xsl:text>)</xsl:text>
+			</xsl:if>
+		</xsl:otherwise>
+	</xsl:choose>
+	<xsl:choose>
+		<xsl:when test="PublisherStreamingAllowed=''">
+			<xsl:text> - Publisher Streaming Allowed Unknown</xsl:text>
+		</xsl:when>
+		<xsl:otherwise>
+			<xsl:text> - Publisher Streaming Allowed </xsl:text><xsl:value-of select="Publisher/PublisherStreamingAllowed"/>
+		</xsl:otherwise>
+	</xsl:choose>
+</xsl:template>
+
+</xsl:stylesheet>